/* SAS code to analyze data from Leisure  
   World Study of endometrial cancer.
   This code is stored as lworld.sas */

/* This file contains 315 records with data 
   on cases and controls from the Leisure World 
   study of endometrial cancer as related to 
   treatment with estrogens for menopausal syptoms 
   and other risk factors.  See the article
   by Mack et al in NEJM 294:1262-1267, 1976 
   for a full description.

The variables are as follows:

Number  Name        Description             Codes/Range
-------------------------------------------------------------------------
   1    GROUP       Matched group indicator    1-63
   2    CASE        Case-control indicator  1 = Case; 0 = control
   3    AGE         Age in years            55-84
   4    AGEG        Age group indicator     1 = 55-64; 2 = 65-74; 3 = 75+
   5    EST         Estrogen usage          1 = No; 2 = Yes
   6    GALL        Gallbladder disease     1 = No; 2 = Yes
   7    HYP         Hypertension            1 = No; 2 = Yes 
   8    OB          Obesity                 1 = No; 2 = Yes; 3 = Unknown
   9    NON         Non-estrogen drug       1 = No; 2 = Yes
-------------------------------------------------------------------------
The nine variables may be read either in free format or using the Fortran
format (1x,9f5.0).  AGEG is based on the age of the case in each matched
set.
*/



data set1;
  infile "c:\st565\lworld.dat";
  input group case age ageg est gall hyp ob non;
  if(case=0) then case=2;
  est=est-1;
  gall=gall-1;
  hyp=hyp-1;
  oby=ob-1;
  if(oby=2) then oby=0;
  obu=(ob-1-oby)/2;
  non=non-1;
  run;

proc print data=set1; run;

proc phreg data=set1;
  model case = est gall hyp oby obu non / ties=discrete rl;
  strata group;
  run;