PROC IMPORT OUT=d
  DATAFILE="C:\z\Courses\Smicroarray07\SoybeanLoop\SASdata.txt" 
  DBMS=TAB REPLACE;
  GETNAMES=YES;
  DATAROW=2; 
RUN;

proc print data=d (obs=30);
run;

data temp;  set d;
  if geneID=1;
run;

ods trace on;
run;

proc mixed data=temp;
  class Array Dye Sample rep daf;
  model y=dye daf / ddfm=kr outp=resids;
  random rep Array Sample;
  lsmeans daf;
  estimate '30-25' daf -1 1 0 0 0;
  estimate '40-30' daf 0 -1 1 0 0;
  estimate '45-40' daf 0 0 -1 1 0;
  estimate '50-45' daf 0 0 0 -1 1;
run;

ods trace off;
run;

ods noresults;
run;

ods listing close;
run;

options nomlogic nonotes;

proc mixed data=d;
  class Array Dye Sample rep daf;
  model y=dye daf / ddfm=kr outp=resids;
  random rep Array Sample;
  lsmeans daf;
  estimate '30-25' daf -1 1 0 0 0;
  estimate '40-30' daf 0 -1 1 0 0;
  estimate '45-40' daf 0 0 -1 1 0;
  estimate '50-45' daf 0 0 0 -1 1;
  by geneID;
  ods output covparms=varcomps;
  ods output tests3=results;
  ods output lsmeans=means;
  ods output estimates=estimates;
run;

ods listing;
run;

proc print data=varcomps (obs=10);
run;

proc print data=results (obs=10);
run;

proc print data=means (obs=10);
run;

proc print data=estimates (obs=10);
run;

data results; set results;
  p=1*probf;
  drop probf;
run;

data estimates; set estimates;
  p=1*probt;
  drop probt;
run;

PROC EXPORT DATA=varcomps 
            OUTFILE= "C:\z\Courses\Smicroarray07\SoybeanLoop\varcomps.txt" 
            DBMS=TAB REPLACE;
RUN;

PROC EXPORT DATA=results 
            OUTFILE= "C:\z\Courses\Smicroarray07\SoybeanLoop\results.txt" 
            DBMS=TAB REPLACE;
RUN;

PROC EXPORT DATA=means 
            OUTFILE= "C:\z\Courses\Smicroarray07\SoybeanLoop\means.txt" 
            DBMS=TAB REPLACE;
RUN;

PROC EXPORT DATA=estimates 
            OUTFILE= "C:\z\Courses\Smicroarray07\SoybeanLoop\estimates.txt" 
            DBMS=TAB REPLACE;
RUN;

PROC EXPORT DATA=resids 
            OUTFILE= "C:\z\Courses\Smicroarray07\SoybeanLoop\resids.txt" 
            DBMS=TAB REPLACE;
RUN;